home *** CD-ROM | disk | FTP | other *** search
/ LOGIC Apps / Logic-APPLE_II_APPS.iso / mac / LOGIC Apple II 5.25" Library - ProDOS / PRO001.dsk / FIN / INVESTMENT.ANAL.bas < prev    next >
BASIC Source File  |  2012-02-16  |  6KB  |  142 lines
  1. 1  HOME : PRINT : PRINT : PRINT : PRINT : PRINT : PRINT : PRINT "COMMON BASIC PROGRAMS--VOL.1"
  2. 2  PRINT : PRINT "ADAPTED FOR THE APPLE II BY JOSEPH BOLUS"
  3. 3  PRINT "FEB.9,1978": FOR  I6 = 1  TO  5000: NEXT  I6
  4. 10  DEF   FN A(A) =  INT(A *100 +.5)/100
  5. 20  HOME 
  6. 30  PRINT  "** INVESTMENTS,ANNUITY,AND FORECASTS **"
  7. 40  PRINT : PRINT 
  8. 50  PRINT  "1. FUTURE VALUE OF AN INVESTMENT": PRINT 
  9. 60  PRINT  "2. ANNUITY": PRINT 
  10. 70  PRINT  "3. REGULAR DEPOSITS": PRINT 
  11. 80  PRINT  "4. REGULAR WITHDRAWALS FROM INVESTMENTS": PRINT 
  12. 90  PRINT  "5. INITIAL INVESTMENT ": PRINT 
  13. 100  PRINT  "6. NOMINAL INTEREST RATE ON INVESTMENTS": PRINT 
  14. 110  PRINT  "7. FORECASTS (TREND LINE)": PRINT 
  15. 120  PRINT  "8. QUIT"
  16. 130  PRINT : PRINT : INPUT "WHICH? ";RE%
  17. 135  IF  RE% <0   THEN  10
  18. 140  ON  RE%  GOTO  1000,2000,3000,4000,5000,6000,7000,8000
  19. 150  GOTO  10
  20. 1000  HOME 
  21. 1010  PRINT   TAB( 2);" "
  22. 1015  PRINT   CHR$(7); CHR$(7); CHR$(7);
  23. 1020  PRINT  "*** FUTURE VALUE OF AN INVESTMENT ***"
  24. 1025  PRINT : PRINT 
  25. 1030  PRINT  CHR$(7);: INPUT "INITIAL INVESTMENT? ";P
  26. 1050  PRINT  CHR$(7);: INPUT "NOMINAL INTEREST RATE? ";I
  27. 1070  PRINT  CHR$(7);: INPUT "NUMBER OF COMPOUNDING PERIODS/YR.? ";N
  28. 1080  PRINT  CHR$(7);: INPUT "NUMBER OF YEARS? ";Y
  29. 1110 I = I/N/100
  30. 1120 T = P *(1 +I) ^(N *Y)
  31. 1125  PRINT : PRINT : POKE  50,63
  32. 1128 A = T:A =  FN A(T)
  33. 1130  PRINT "FUTURE VALUE = $";A: PRINT : POKE 50,255
  34. 1140  INPUT "MORE DATA? ";RE$: IF RE$ = "Y"  OR RE$ = "YES"  THEN 1000
  35. 1150  GOTO  10
  36. 2000  HOME 
  37. 2010  PRINT   CHR$(7); CHR$(7); CHR$(7);: PRINT   TAB( 2);" "
  38. 2015  PRINT   TAB( 16);"ANNUITY"
  39. 2020  PRINT : PRINT 
  40. 2030  PRINT  CHR$(7);: INPUT "AMOUNT OF REGULAR DEPOSITS? ";R
  41. 2050  PRINT  CHR$(7);: INPUT "NOMINAL INTEREST RATE? ";I
  42. 2070  PRINT  CHR$(7);: INPUT "NUMBER OF DEPOSITS/YR.? ";N
  43. 2090  PRINT  CHR$(7);: INPUT "NUMBER OF YEARS? ";Y
  44. 2110 I = I/N/100
  45. 2120 T = R *((1 +I) ^(N *Y) -1)/I
  46. 2125 A = T:A =  FN A(A): POKE  50,63: PRINT 
  47. 2130  PRINT "FUTURE VALUE = $";A: POKE 50,255: PRINT : PRINT 
  48. 2150  INPUT "MORE DATA? ";RE$: IF RE$ = "Y"  OR RE$ = "YES"  THEN 2000
  49. 2160  GOTO  10
  50. 3000  HOME 
  51. 3005  PRINT   CHR$(7); CHR$(7); CHR$(7)
  52. 3010  PRINT   TAB( 12);"REGULAR DEPOSITS": PRINT : PRINT 
  53. 3030  PRINT  CHR$(7);: INPUT "NUMBER OF YEARS? ";Y
  54. 3050  PRINT  CHR$(7);"TOTAL VALUE DESIRED IN ACCOUNT AFTER    ";Y;: INPUT " YEARS? ";T
  55. 3055  PRINT   CHR$(7);
  56. 3060  INPUT "NOMINAL INTEREST RATE? ";I
  57. 3070  PRINT  CHR$(7);: INPUT "NUMBER OF DEPOSITS/YR.? ";N
  58. 3110 I = I/N/100
  59. 3120 R = T *I/((I +1) ^(N *Y) -1)
  60. 3125  PRINT : PRINT : POKE  50,63
  61. 3128 A = R:A =  FN A(A)
  62. 3130  PRINT "REGULAR DEPOSITS =$";A: PRINT : PRINT : POKE  50,255
  63. 3140  INPUT "MORE DATA? ";RE$: IF RE$ = "Y"  OR RE$ = "YES"  THEN 3000
  64. 3150  GOTO  10
  65. 4000  HOME 
  66. 4010  PRINT   CHR$(7); CHR$(7); CHR$(7): PRINT " REGULAR WITHDRAWALS FROM AN INVESTMENT"
  67. 4020  PRINT : PRINT 
  68. 4030  PRINT  CHR$(7);: INPUT "INITIAL INVESTMENT? ";P
  69. 4050  PRINT  CHR$(7);: INPUT "NOMINAL INTEREST RATE? ";I
  70. 4060  PRINT  CHR$(7);: INPUT "NUMBER OF WITHDRAWALS/YR.? ";N
  71. 4070  PRINT  CHR$(7);: INPUT "NUMBER OF YEARS? ";Y
  72. 4110 I = I/N/100
  73. 4120 R = P *(I/((1 +I) ^(N *Y) -1) +I)
  74. 4125  PRINT : PRINT : POKE  50,63
  75. 4128 A = R:A =  FN A(A)
  76. 4130  PRINT "AMOUNT OF EACH WITHDRAWAL = $";A
  77. 4140  POKE  50,255: PRINT : PRINT 
  78. 4150  INPUT "MORE DATA? ";RE$: IF RE$ = "Y"  OR RE$ = "YES"  THEN 4000
  79. 4160  GOTO  10
  80. 5000  HOME 
  81. 5005  PRINT   CHR$(7); CHR$(7); CHR$(7);
  82. 5010  PRINT : PRINT   TAB( 11);"INITIAL INVESTMENT"
  83. 5020  PRINT : PRINT 
  84. 5025  PRINT   CHR$(7);
  85. 5030  INPUT "NUMBER OF YEARS? ";Y
  86. 5040  PRINT  CHR$(7);: PRINT "TOTAL VALUE DESIRED AFTER ";Y: INPUT "YEARS? ";T
  87. 5050  PRINT  CHR$(7);: INPUT "NUMBER OF COMPOUNDING PERIODS/YR.? ";N
  88. 5060  PRINT  CHR$(7);: INPUT "NOMINAL INTEREST RATE? ";I
  89. 5070  PRINT : PRINT 
  90. 5100 I = I/N/100
  91. 5120 P = T/(1 +I) ^(N *Y)
  92. 5125  POKE  50,63:A = P:A =  FN A(A)
  93. 5130  PRINT "INITIAL INVESTMENT = $";A
  94. 5140  POKE  50,255: PRINT : PRINT 
  95. 5150  INPUT "MORE DATA? ";RE$: IF RE$ = "Y"  OR RE$ = "YES"  THEN 5000
  96. 5160  GOTO  10
  97. 6000  HOME 
  98. 6005  PRINT   CHR$(7); CHR$(7); CHR$(7)
  99. 6010  PRINT " NOMINAL INTEREST RATE ON INVESTMENTS"
  100. 6020  PRINT : PRINT 
  101. 6030  PRINT  CHR$(7);: INPUT "PRINCIPLE? ";P
  102. 6040  PRINT  CHR$(7);: INPUT "TOTAL VALUE? ";T
  103. 6050  PRINT  CHR$(7);: INPUT "NUMBER OF YEARS? ";Y
  104. 6060  PRINT  CHR$(7);: INPUT "NO. OF COMPOUNDING PERIODS/YR.? ";N
  105. 6070  PRINT : PRINT 
  106. 6110 I2 = N *((T/P) ^(1/(N *Y)) -1) *100
  107. 6120  POKE  50,63:A = I2:A =  FN A(A)
  108. 6130  PRINT "NOMINAL INTEREST RATE =";A;"%"
  109. 6140  PRINT : PRINT : POKE  50,255
  110. 6150  INPUT "MORE DATA? ";RE$: IF RE$ = "Y"  OR RE$ = "YES"  THEN 6000
  111. 6160  GOTO  10
  112. 7000  HOME 
  113. 7005  PRINT   CHR$(7); CHR$(7); CHR$(7)
  114. 7010  PRINT   TAB( 9) ;"FORECASTS (TREND LINE)"
  115. 7020  PRINT : PRINT 
  116. 7030  INPUT "NUMBER OF KNOWN POINTS? ";N: PRINT 
  117. 7035  IF  N <2   THEN  7037
  118. 7036  GOTO  7040
  119. 7037  PRINT "YOU MUST USE AT LEAST 2 POINTS": FOR I9 = 1 TO 2000: NEXT I9: GOTO 7000
  120. 7040 J = 0:K = 0:L = 0:M = 0:R2 = 0
  121. 7100  FOR  I = 1  TO  N
  122. 7110  PRINT "X,Y OF POINT? ";I;: INPUT X,Y
  123. 7130 J = J +X:K = K +Y:L = L +X ^2:M = M +Y ^2:R2 = R2 +X *Y
  124. 7155  PRINT   CHR$(7); CHR$(7);
  125. 7180  NEXT  I
  126. 7190 B = (N *R2 -K *J)/(N *L -J ^2):A = (K -B *J)/N
  127. 7230 J = B *(R2 -J *K/N):M = M -K ^2/N:K = M -J:R2 = J/M
  128. 7240  HOME 
  129. 7250  PRINT "READY TO START FORECASTING..."
  130. 7255 CR =  SQR(R2):CR = CR *100:CR =  FN A(CR)
  131. 7260  PRINT "GOODNESS OF FIT IS ";CR;"%"
  132. 7270  POKE  34,5: POKE  35,23
  133. 7280  PRINT  "FORECASTING (ENTER X=0 TO QUIT)": PRINT 
  134. 7300  INPUT "X =? ";X: IF X = 0  THEN 7500
  135. 7310  POKE  50,63
  136. 7315 Y2 = A +B *X:Y2 =  FN A(Y2)
  137. 7320  PRINT "Y =";Y2: PRINT : POKE  50,255
  138. 7330  GOTO  7300
  139. 7500  TEXT 
  140. 7510  GOTO  10
  141. 8000  HOME 
  142. 8010  END